move the model loading to a plugin

Note, since the models are stateless I'm keeping them in attributes on
the plugin itself. This is not the most common pattern, but all it
really does is keep instances late-built but cached

Author: jberger

lib/MetaCPAN/API.pm

@@ -23,8 +23,6 @@ use Mojo::Base 'Mojolicious';
 use Config::ZOMG ();
 use File::Temp   ();
 use List::Util qw( any );
-use MetaCPAN::Model::Search  ();
-use MetaCPAN::Model::User    ();
 use MetaCPAN::Script::Runner ();
 use Search::Elasticsearch    ();
 use Try::Tiny qw( catch try );
@@ -36,19 +34,6 @@ has es => sub {
     );
 };
 
-has model_search => sub {
-    my $self = shift;
-    return MetaCPAN::Model::Search->new(
-        es    => $self->es,
-        index => 'cpan',
-    );
-};
-
-has model_user => sub {
-    my $self = shift;
-    return MetaCPAN::Model::User->new( es => $self->es, );
-};
-
 sub startup {
     my $self = shift;
 
@@ -84,6 +69,7 @@ sub startup {
     $self->minion->add_task(
         index_favorite => $self->_gen_index_task_sub('favorite') );
 
+    $self->plugin('MetaCPAN::API::Plugin::Model');
     $self->_set_up_routes;
 }
 

lib/MetaCPAN/API/Controller/Admin.pm

@@ -6,7 +6,7 @@ sub identity_search_form { }
 
 sub search_identities {
     my $self = shift;
-    my $data = $self->app->model_user->lookup( $self->param('name'),
+    my $data = $self->model->user->lookup( $self->param('name'),
         $self->param('key') );
     $self->stash( user_data => $data );
     $self->render('admin/search_identities');

lib/MetaCPAN/API/Controller/Search.pm

@@ -2,14 +2,12 @@ package MetaCPAN::API::Controller::Search;
 
 use Mojo::Base 'Mojolicious::Controller';
 
-has model => sub { shift->app->model_search };
-
 sub first {
     my $c = shift;
     return unless $c->openapi->valid_input;
     my $args = $c->validation->output;
 
-    my $results = $c->model->search_for_first_result( $args->{q} );
+    my $results = $c->model->search->search_for_first_result( $args->{q} );
     return $c->render( openapi => $results ) if $results;
     $c->rendered(404);
 }
@@ -21,7 +19,7 @@ sub web {
 
     my @search = ( @{$args}{qw/q from size/} );
     push @search, $args->{collapsed} if exists $args->{collapsed};
-    my $results = $c->model->search_web(@search);
+    my $results = $c->model->search->search_web(@search);
 
     return $c->render( json => $results );
 }

lib/MetaCPAN/API/Plugin/Model.pm

@@ -0,0 +1,34 @@
+package MetaCPAN::API::Plugin::Model;
+
+use Mojo::Base 'Mojolicious::Plugin';
+
+use Carp                    ();
+use MetaCPAN::Model::Search ();
+use MetaCPAN::Model::User   ();
+
+has app => sub { Carp::croak 'app is required' }, weak => 1;
+
+has search => sub {
+    my $self = shift;
+    return MetaCPAN::Model::Search->new(
+        es    => $self->app->es,
+        index => 'cpan',
+    );
+};
+
+has user => sub {
+    my $self = shift;
+    return MetaCPAN::Model::User->new( es => $self->app->es );
+};
+
+sub register {
+    my ( $plugin, $app, $conf ) = @_;
+    $plugin->app($app);
+
+    # cached models
+    $app->helper( 'model.search' => sub { $plugin->search } );
+    $app->helper( 'model.user'   => sub { $plugin->user } );
+}
+
+1;
+