Use pg instead if available

Author: josevalim

lib/phoenix/pubsub/application.ex

@@ -0,0 +1,18 @@
+defmodule Phoenix.PubSub.Application do
+  use Application
+
+  def start(_, _) do
+    children = pg_children()
+    Supervisor.start_link(children, strategy: :one_for_one)
+  end
+
+  if Code.ensure_loaded?(:pg) do
+    defp pg_children() do
+      [%{id: :pg, start: {:pg, :start_link, [Phoenix.PubSub]}}]
+    end
+  else
+    defp pg_children() do
+      []
+    end
+  end
+end

lib/phoenix/pubsub/pg2.ex

@@ -1,6 +1,6 @@
 defmodule Phoenix.PubSub.PG2 do
   @moduledoc """
-  Phoenix PubSub adapter based on `:pg2`.
+  Phoenix PubSub adapter based on `:pg`/`:pg2`.
 
   It runs on Distributed Erlang and is the default adapter.
   """
@@ -15,7 +15,7 @@ defmodule Phoenix.PubSub.PG2 do
 
   @impl true
   def broadcast(adapter_name, topic, message, dispatcher) do
-    case :pg2.get_members(pg2_namespace(adapter_name)) do
+    case pg_members(adapter_name) do
       {:error, {:no_such_group, _}} ->
         {:error, :no_such_group}
 
@@ -51,12 +51,11 @@ defmodule Phoenix.PubSub.PG2 do
 
   @impl true
   def init({name, adapter_name}) do
-    pg2_group = pg2_namespace(adapter_name)
-    :ok = :pg2.create(pg2_group)
-    :ok = :pg2.join(pg2_group, self())
+    :ok = pg_join(adapter_name)
     {:ok, name}
   end
 
+  @impl true
   def handle_info({:forward_to_local, topic, message, dispatcher}, pubsub) do
     Phoenix.PubSub.local_broadcast(pubsub, topic, message, dispatcher)
     {:noreply, pubsub}
@@ -67,5 +66,26 @@ defmodule Phoenix.PubSub.PG2 do
     {:noreply, pubsub}
   end
 
-  defp pg2_namespace(server_name), do: {:phx, server_name}
+  if Code.ensure_loaded?(:pg) do
+    defp pg_members(adapter_name) do
+      :pg.get_members(Phoenix.PubSub, adapter_name)
+    end
+
+    defp pg_join(adapter_name) do
+      :ok = :pg.join(Phoenix.PubSub, adapter_name, self())
+    end
+  else
+    defp pg_members(adapter_name) do
+      :pg2.get_members(pg2_namespace(adapter_name))
+    end
+
+    defp pg_join(adapter_name) do
+      namespace = pg2_namespace(adapter_name)
+      :ok = :pg2.create(namespace)
+      :ok = :pg2.join(namespace, self())
+      :ok
+    end
+
+    defp pg2_namespace(adapter_name), do: {:phx, adapter_name}
+  end
 end

mix.exs

@@ -22,6 +22,7 @@ defmodule Phoenix.PubSub.Mixfile do
 
   def application do
     [
+      mod: {Phoenix.PubSub.Application, []},
       applications: [:logger, :crypto],
     ]
   end