OpenMC/cmake/Modules/GetVersionFromGit.cmake at 1603dc545da94ed9414c2b03bcf5faef33b2c826 · ahnaf-tahmid-chowdhury/OpenMC · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
# GetVersionFromGit.cmake
# Standalone script to retrieve versioning information from Git or .git_archival.txt.
# Customizable for any project by setting variables before including this file.

# Configurable variables:
#   - VERSION_PREFIX: Prefix for version tags (default: "v").
#   - VERSION_SURFIX: Suffix for version tags (default: "[~+-]([a-zA-Z0-9]+)").
#   - VERSION_REGEX: Regex to extract version (default: "(?[0-9]+\\.[0-9]+\\.[0-9]+)").
#   - ARCHIVAL_FILE: Path to .git_archival.txt (default: "${CMAKE_SOURCE_DIR}/.git_archival.txt").
#   - DESCRIBE_NAME_KEY: Key for describe name in .git_archival.txt (default: "describe-name: ").
#   - COMMIT_HASH_KEY: Key for commit hash in .git_archival.txt (default: "commit: ").

# Default Format Example:
#   1.2.3 v1.2.3 v1.2.3-rc1

set(VERSION_PREFIX "v" CACHE STRING "Prefix used in version tags")
set(VERSION_SUFFIX "[~+-]([a-zA-Z0-9]+)" CACHE STRING "Suffix used in version tags")
set(VERSION_REGEX "?([0-9]+\\.[0-9]+\\.[0-9]+)" CACHE STRING "Regex for extracting version")
set(ARCHIVAL_FILE "${CMAKE_SOURCE_DIR}/.git_archival.txt" CACHE STRING "Path to .git_archival.txt")
set(DESCRIBE_NAME_KEY "describe-name: " CACHE STRING "Key for describe name in .git_archival.txt")
set(COMMIT_HASH_KEY "commit: " CACHE STRING "Key for commit hash in .git_archival.txt")


# Combine prefix and regex
set(VERSION_REGEX_WITH_PREFIX "^${VERSION_PREFIX}${VERSION_REGEX}")

# Ensure Git is available
find_package(Git REQUIRED)

# Attempt to retrieve version from Git
if(EXISTS "${CMAKE_SOURCE_DIR}/.git" AND GIT_FOUND)
    message(STATUS "Using git describe for versioning")

    # Extract the version string
    execute_process(
        COMMAND git describe --tags --dirty
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
        OUTPUT_VARIABLE VERSION_STRING
        OUTPUT_STRIP_TRAILING_WHITESPACE
    )

    # Extract the commit hash
    execute_process(
        COMMAND git rev-parse HEAD
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
        OUTPUT_VARIABLE COMMIT_HASH
        OUTPUT_STRIP_TRAILING_WHITESPACE
    )
else()
    message(STATUS "Using archival file for versioning: ${ARCHIVAL_FILE}")
    if(EXISTS "${ARCHIVAL_FILE}")
        file(READ "${ARCHIVAL_FILE}" ARCHIVAL_CONTENT)

        # Extract the describe-name line
        string(REGEX MATCH "${DESCRIBE_NAME_KEY}([^\\n]+)" VERSION_STRING "${ARCHIVAL_CONTENT}")
        if(VERSION_STRING MATCHES "${DESCRIBE_NAME_KEY}(.*)")
            set(VERSION_STRING "${CMAKE_MATCH_1}")
        else()
            message(FATAL_ERROR "Could not extract version from ${ARCHIVAL_FILE}")
        endif()

        # Extract the commit hash
        string(REGEX MATCH "${COMMIT_HASH_KEY}([a-f0-9]+)" COMMIT_HASH "${ARCHIVAL_CONTENT}")
        if(COMMIT_HASH MATCHES "${COMMIT_HASH_KEY}([a-f0-9]+)")
            set(COMMIT_HASH "${CMAKE_MATCH_1}")
        else()
            message(FATAL_ERROR "Could not extract commit hash from ${ARCHIVAL_FILE}")
        endif()
    else()
        message(FATAL_ERROR "Neither git describe nor ${ARCHIVAL_FILE} is available for versioning.")
    endif()
endif()

# Ensure version string format
if(VERSION_STRING MATCHES "${VERSION_REGEX_WITH_PREFIX}")
    set(VERSION_NO_SUFFIX "${CMAKE_MATCH_1}")
else()
    message(FATAL_ERROR "Invalid version format: Missing base version in ${VERSION_STRING}")
endif()

# Check for development state
if(VERSION_STRING MATCHES "-([0-9]+)-g([0-9a-f]+)")
    set(DEV_STATE "true")
    set(COMMIT_COUNT "${CMAKE_MATCH_1}")
    string(REGEX REPLACE "-([0-9]+)-g([0-9a-f]+)" "" VERSION_WITHOUT_META "${VERSION_STRING}")
else()
    set(DEV_STATE "false")
    set(VERSION_WITHOUT_META "${VERSION_STRING}")
endif()

# Check for dirty state
if(VERSION_STRING MATCHES "-dirty")
    set(DIRTY_STATE "true")
else()
    set(DIRTY_STATE "false")
endif()

# Check for extra version
if(VERSION_WITHOUT_META MATCHES "${VERSION_SUFFIX}")
    set(VERSION_EXTRA "${CMAKE_MATCH_1}")
else()
    set(VERSION_EXTRA "")
endif()

# Split and set version components
string(REPLACE "." ";" VERSION_LIST "${VERSION_NO_SUFFIX}")
list(GET VERSION_LIST 0 VERSION_MAJOR)
list(GET VERSION_LIST 1 VERSION_MINOR)
list(GET VERSION_LIST 2 VERSION_PATCH)

# Increment patch number for dev versions
if(DEV_STATE)
    math(EXPR VERSION_PATCH "${VERSION_PATCH} + 1")
endif()

# Export variables
set(PROJECT_VERSION_MAJOR "${VERSION_MAJOR}")
set(PROJECT_VERSION_MINOR "${VERSION_MINOR}")
set(PROJECT_VERSION_PATCH "${VERSION_PATCH}")
set(PROJECT_VERSION_EXTRA "${VERSION_EXTRA}")
set(PROJECT_VERSION "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}")
set(PROJECT_COMMIT_HASH "${COMMIT_HASH}")
set(PROJECT_DIRTY_STATE "${DIRTY_STATE}")
set(PROJECT_DEV_STATE "${DEV_STATE}")
set(PROJECT_COMMIT_COUNT "${COMMIT_COUNT}")