Separate Transit reader and writer options

As mentioned in issue dakrone#292, the Transit reader and writer require
different options. At the moment `:transit-opts` is passed to both
reader and writer, which means you can either specify read handlers or
write handlers, but not both. Transit will complain if `:handlers` is a
mix of read and write handlers.

This patch splits up `:transit-opts` into a `:encode` and `:decode`
section. The options in `:encode` will be passed to the writer, the
options in `:decode` to the reader.

Author: r0man

README.org

@@ -270,12 +270,16 @@ content encodings.
 ;; Send form params as a Transit encoded JSON body (POST or PUT) with options
 (client/post "http://site.com" {:form-params {:foo "bar"}
                                 :content-type :transit+json
-                                :transit-opts {:handlers {}}})
+                                :transit-opts
+                                {:encode {:handlers {}}
+                                 :decode {:handlers {}}}})
 
 ;; Send form params as a Transit encoded MessagePack body (POST or PUT) with options
 (client/post "http://site.com" {:form-params {:foo "bar"}
                                 :content-type :transit+msgpack
-                                :transit-opts {:handlers {}}})
+                                :transit-opts
+                                {:encode {:handlers {}}
+                                 :decode {:handlers {}}}})
 
 ;; Multipart form uploads/posts
 ;; takes a vector of maps, to preserve the order of entities, :name

src/clj_http/client.clj

@@ -72,7 +72,7 @@
   {:pre [transit-enabled?]}
   (let [reader (ns-resolve 'cognitect.transit 'reader)
         read (ns-resolve 'cognitect.transit 'read)]
-    (read (reader in type opts))))
+    (read (reader in type (:decode opts)))))
 
 (defn ^:dynamic transit-encode
   "Resolve and apply Transit's JSON/MessagePack encoding."
@@ -81,7 +81,7 @@
   (let [output (ByteArrayOutputStream.)
         writer (ns-resolve 'cognitect.transit 'writer)
         write (ns-resolve 'cognitect.transit 'write)]
-    (write (writer output type opts) out)
+    (write (writer output type (:encode opts)) out)
     (.toByteArray output)))
 
 (defn ^:dynamic json-encode

test/clj_http/test/client_test.clj

@@ -7,6 +7,7 @@
             [clojure.string :as str]
             [clojure.java.io :refer [resource]]
             [clojure.test :refer :all]
+            [cognitect.transit :as transit]
             [ring.util.codec :refer [form-decode-str]]
             [ring.middleware.nested-params :refer [parse-nested-keys]])
   (:import (java.net UnknownHostException)
@@ -467,6 +468,26 @@
              client/parse-url
              :user-info))))
 
+(defrecord Point [x y])
+
+(def write-point
+  "Write a point in Transit format."
+  (transit/write-handler
+   (constantly "point")
+   (fn [point] [(:x point) (:y point)])
+   (constantly nil)))
+
+(def read-point
+  "Read a point in Transit format."
+  (transit/read-handler
+   (fn [[x y]]
+     (->Point x y))))
+
+(def transit-opts
+  "Transit read and write options."
+  {:encode {:handlers {Point write-point}}
+   :decode {:handlers {"point" read-point}}})
+
 (deftest apply-on-form-params
   (testing "With form params"
     (let [param-client (client/wrap-form-params identity)
@@ -522,7 +543,7 @@
   (testing "With EDN form params"
     (doseq [method [:post :put :patch]]
       (let [param-client (client/wrap-form-params identity)
-            params {:param1 "value1" :param2 "value2"}
+            params {:param1 "value1" :param2 (Point. 1 2)}
             resp (param-client {:request-method method
                                 :content-type :edn
                                 :form-params params})]
@@ -533,12 +554,14 @@
   (testing "With Transit/JSON form params"
     (doseq [method [:post :put :patch]]
       (let [param-client (client/wrap-form-params identity)
-            params {:param1 "value1" :param2 "value2"}
+            params {:param1 "value1" :param2 (Point. 1 2)}
             resp (param-client {:request-method method
                                 :content-type :transit+json
-                                :form-params params})]
+                                :form-params params
+                                :transit-opts transit-opts})]
         (is (= params (client/parse-transit
-                       (ByteArrayInputStream. (:body resp)) :json)))
+                       (ByteArrayInputStream. (:body resp))
+                       :json transit-opts)))
         (is (= "application/transit+json" (:content-type resp)))
         (is (not (contains? resp :form-params))))))
 
@@ -548,9 +571,11 @@
             params {:param1 "value1" :param2 "value2"}
             resp (param-client {:request-method method
                                 :content-type :transit+msgpack
-                                :form-params params})]
+                                :form-params params
+                                :transit-opts transit-opts})]
         (is (= params (client/parse-transit
-                       (ByteArrayInputStream. (:body resp)) :msgpack)))
+                       (ByteArrayInputStream. (:body resp))
+                       :msgpack transit-opts)))
         (is (= "application/transit+msgpack" (:content-type resp)))
         (is (not (contains? resp :form-params))))))