Repository navigation
Expand file tree
/
Copy pathCMakeLists.txt
More file actions
322 lines (296 loc) · 9.89 KB
/
Copy pathCMakeLists.txt
File metadata and controls
322 lines (296 loc) · 9.89 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
# Copyright 2025 DeepMind Technologies Limited
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
cmake_minimum_required(VERSION 3.16)
include(third_party_deps/atkinson_hyperlegible_mono)
include(third_party_deps/atkinson_hyperlegible_next)
include(third_party_deps/dear_imgui)
include(third_party_deps/font_awesome)
include(third_party_deps/implot)
include(third_party_deps/libwebp)
include(third_party_deps/sdl2)
set(MUJOCO_STUDIO_PLATFORM_TARGET_NAME mujoco_studio_platform)
add_library(${MUJOCO_STUDIO_PLATFORM_TARGET_NAME} STATIC)
target_sources(${MUJOCO_STUDIO_PLATFORM_TARGET_NAME}
PRIVATE
hal/graphics_mode.cc
hal/graphics_mode.h
hal/window.cc
hal/window.h
io/resources.cc
io/resources.h
render/model_scene.cc
render/model_scene.h
sim/model_holder.cc
sim/model_holder.h
sim/sim_history.cc
sim/sim_history.h
sim/sim_profiler.cc
sim/sim_profiler.h
sim/step_control.cc
sim/step_control.h
ux/camera_control.cc
ux/camera_control.h
ux/console.cc
ux/console.h
ux/enum_utils.h
ux/file_dialog.h
ux/fonts.cc
ux/fonts.h
ux/gui.cc
ux/gui.h
ux/gui_helpers.cc
ux/gui_helpers.h
ux/gui_spec.cc
ux/gui_spec.h
ux/imgui_widgets.cc
ux/imgui_widgets.h
ux/interaction.cc
ux/interaction.h
ux/picture_gui.h
ux/picture_gui.cc
ux/plugin.cc
ux/plugin.h
ux/spec_editor.cc
ux/spec_editor.h
ux/theme.cc
ux/theme.h
ux/well_tempered.h
)
if(NOT WIN32)
target_sources(${MUJOCO_STUDIO_PLATFORM_TARGET_NAME}
PRIVATE
ux/object_launcher_plugin.cc
)
endif()
if(APPLE)
set_source_files_properties(hal/window_osx.mm PROPERTIES
COMPILE_FLAGS "-x objective-c++")
target_sources(${MUJOCO_STUDIO_PLATFORM_TARGET_NAME} PRIVATE
hal/window_osx.mm
ux/file_dialog_cocoa.mm
)
elseif(UNIX AND NOT APPLE)
target_sources(${MUJOCO_STUDIO_PLATFORM_TARGET_NAME} PRIVATE
ux/file_dialog_zenity.cc
)
elseif(WIN32)
target_sources(${MUJOCO_STUDIO_PLATFORM_TARGET_NAME} PRIVATE
ux/file_dialog_win.cc
)
else()
target_sources(${MUJOCO_STUDIO_PLATFORM_TARGET_NAME} PRIVATE
ux/file_dialog.cc
)
endif()
target_include_directories(${MUJOCO_STUDIO_PLATFORM_TARGET_NAME}
PRIVATE
${PROJECT_SOURCE_DIR}
${PROJECT_SOURCE_DIR}/include
${PROJECT_SOURCE_DIR}/src
)
mujoco_add_dear_imgui_sdl2_backend()
target_link_libraries(${MUJOCO_STUDIO_PLATFORM_TARGET_NAME}
dear_imgui
dear_imgui_SDL2
dear_imgui_OpenGL3
dear_imgui_stdlib
implot
mujoco::filament
SDL2::SDL2-static
)
add_library(mujoco::platform ALIAS ${MUJOCO_STUDIO_PLATFORM_TARGET_NAME})
if(NOT TARGET mujoco_studio_assets)
set(STUDIO_ASSETS_STAGE_DIR ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/assets)
add_custom_target(mujoco_studio_assets
COMMAND ${CMAKE_COMMAND} -E make_directory "${STUDIO_ASSETS_STAGE_DIR}"
COMMAND ${CMAKE_COMMAND} -E copy_if_different
"${CMAKE_BINARY_DIR}/_deps/atkinson_hyperlegible_next-src/fonts/variable/AtkinsonHyperlegibleNext[wght].ttf"
"${CMAKE_BINARY_DIR}/_deps/font_awesome-src/fonts/fontawesome-webfont.ttf"
"${CMAKE_BINARY_DIR}/_deps/atkinson_hyperlegible_mono-src/fonts/ttf/AtkinsonHyperlegibleMono-Regular.ttf"
"${STUDIO_ASSETS_STAGE_DIR}"
COMMENT "Staging Studio fonts into ${STUDIO_ASSETS_STAGE_DIR}")
if(MUJOCO_USE_FILAMENT)
add_custom_command(TARGET mujoco_studio_assets POST_BUILD
COMMAND ${CMAKE_COMMAND} -E copy_directory
${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/../src/render/filament/assets
"${STUDIO_ASSETS_STAGE_DIR}")
add_dependencies(mujoco_studio_assets mujoco_filament_assets)
endif()
endif()
# Common configuration shared between mujoco_studio and mujoco_live.
function(configure_studio_target TARGET_NAME)
target_sources(${TARGET_NAME}
PRIVATE
app.cc
app.h
)
target_include_directories(${TARGET_NAME}
PUBLIC
${PROJECT_SOURCE_DIR}
${PROJECT_SOURCE_DIR}/include
${PROJECT_SOURCE_DIR}/src
)
if (WIN32)
target_compile_definitions(${TARGET_NAME}
PRIVATE
-D_USE_MATH_DEFINES
)
set_target_properties(${TARGET_NAME}
PROPERTIES
VS_DEBUGGER_WORKING_DIRECTORY "${CMAKE_RUNTIME_OUTPUT_DIRECTORY}"
)
endif()
target_link_libraries(${TARGET_NAME}
PRIVATE
absl::flags
absl::flags_parse
dear_imgui
implot
mujoco::mujoco
mujoco::platform
webp
)
# Self-registering plugin TUs (mjPLUGIN_LIB_INIT) have no referenced symbols,
# so the linker discards them when they arrive inside a static archive.
if(APPLE)
target_link_options(${TARGET_NAME} PRIVATE
"-Wl,-force_load,$<TARGET_FILE:mujoco_studio_platform>")
elseif(NOT MSVC)
target_link_options(${TARGET_NAME} PRIVATE
"-Wl,--whole-archive,$<TARGET_FILE:mujoco_studio_platform>,--no-whole-archive")
else()
target_link_options(${TARGET_NAME} PRIVATE
"/WHOLEARCHIVE:$<TARGET_FILE:mujoco_studio_platform>")
endif()
add_dependencies(${TARGET_NAME} mujoco_studio_assets)
get_target_property(IS_BUNDLE ${TARGET_NAME} MACOSX_BUNDLE)
if(IS_BUNDLE)
add_custom_command(
TARGET ${TARGET_NAME}
POST_BUILD
COMMAND ${CMAKE_COMMAND} -E copy_directory
"${STUDIO_ASSETS_STAGE_DIR}"
$<TARGET_FILE_DIR:${TARGET_NAME}>/../Resources/assets
COMMENT "Copying staged assets to bundle Resources"
)
endif()
endfunction()
# Desktop Studio target.
if(NOT EMSCRIPTEN)
if(APPLE)
set(STUDIO_RESOURCE_FILES ${CMAKE_CURRENT_SOURCE_DIR}/../dist/mujoco_studio.icns)
elseif(WIN32)
set(STUDIO_RESOURCE_FILES ${CMAKE_CURRENT_SOURCE_DIR}/../dist/mujoco_studio.rc)
else()
set(STUDIO_RESOURCE_FILES "")
endif()
add_executable(mujoco_studio
main.cc
launcher.cc
launcher.h
${STUDIO_RESOURCE_FILES}
)
if(APPLE AND MUJOCO_BUILD_MACOS_FRAMEWORKS)
set_target_properties(mujoco_studio PROPERTIES
MACOSX_BUNDLE TRUE
INSTALL_RPATH "@executable_path/../Frameworks;@executable_path/../../.."
BUILD_WITH_INSTALL_RPATH TRUE
RESOURCE "${STUDIO_RESOURCE_FILES}"
MACOSX_BUNDLE_ICON_FILE "mujoco_studio.icns"
)
endif()
if(WIN32)
add_custom_command(
TARGET mujoco_studio
PRE_BUILD
COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/../dist/mujoco_studio.ico
${CMAKE_CURRENT_SOURCE_DIR}
POST_BUILD
COMMAND ${CMAKE_COMMAND} -E rm ${CMAKE_CURRENT_SOURCE_DIR}/mujoco_studio.ico
)
endif()
configure_studio_target(mujoco_studio)
if(NOT (APPLE AND MUJOCO_BUILD_MACOS_FRAMEWORKS))
include(TargetAddRpath)
target_add_rpath(
TARGETS
mujoco_studio
INSTALL_DIRECTORY
"${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_BINDIR}"
LIB_DIRS
"${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR}"
DEPENDS
MUJOCO_ENABLE_RPATH
)
endif()
install(
TARGETS mujoco_studio
RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}" COMPONENT studio
BUNDLE DESTINATION "${CMAKE_INSTALL_BINDIR}" COMPONENT studio
)
get_target_property(IS_BUNDLE mujoco_studio MACOSX_BUNDLE)
if(NOT IS_BUNDLE)
install(
DIRECTORY "${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/assets"
DESTINATION "${CMAKE_INSTALL_BINDIR}" COMPONENT studio
)
endif()
endif()
# Browser WASM client for the Web Viewer.
if(EMSCRIPTEN)
add_subdirectory(
${PROJECT_SOURCE_DIR}/python/mujoco/studio/web
${CMAKE_CURRENT_BINARY_DIR}/web
)
endif()
# WASM Live target.
if(EMSCRIPTEN)
set(
MUJOCO_STUDIO_WASM_INITIAL_MEMORY
"1024mb"
CACHE STRING "Initial WebAssembly memory for MuJoCo Live"
)
set(
MUJOCO_STUDIO_WASM_MAXIMUM_MEMORY
"4gb"
CACHE STRING "Maximum WebAssembly memory for MuJoCo Live"
)
add_executable(mujoco_studio)
target_sources(mujoco_studio PRIVATE emscripten.cc)
target_compile_options(mujoco_studio PRIVATE -g)
configure_studio_target(mujoco_studio)
target_link_libraries(mujoco_studio PRIVATE mujoco::render_noop)
# Ensure resource decoder plugins are linked into the WASM binary.
target_link_options(mujoco_studio PRIVATE
"-Wl,--whole-archive,$<TARGET_FILE:mujoco>,--no-whole-archive"
)
# Filament's OpenGL backend requires WebGL2 / full ES3 bindings.
target_link_options(mujoco_studio PRIVATE
--bind
-sUSE_WEBGL2=1
-sFULL_ES3
-sMIN_WEBGL_VERSION=2
-sMAX_WEBGL_VERSION=2
-sALLOW_MEMORY_GROWTH=1
-sASYNCIFY=1
-sFETCH=1
-sGL_PREINITIALIZED_CONTEXT=1
-sSTACK_SIZE=32mb
-sINITIAL_MEMORY=${MUJOCO_STUDIO_WASM_INITIAL_MEMORY}
-sMAXIMUM_MEMORY=${MUJOCO_STUDIO_WASM_MAXIMUM_MEMORY}
-sASSERTIONS=1
-fexceptions
-g
)
endif()