Added clojure-install command and clojure-slime-config function.

Set clojure-src-root to the directory that contains your
clojure-related checkouts, then call clojure-slime-config to set up
slime. If you don't have clojure, contrib, slime, and swank-clojure
installed, use the clojure-install command to get them.

Author: technomancy

clojure-mode.el

@@ -530,6 +530,72 @@ check for contextual indenting."
 ; (put 'lazy-cat 'clojure-indent-function 1)
 ; (put 'lazy-cons 'clojure-indent-function 1)
 
+(defvar clojure-src-root "~/src"
+  "Directory that contains checkouts for Clojure and other libs.
+
+clojure-contrib, slime, and swank-clojure should be here too. Use
+the `clojure-install' command to check these out and configure
+them for you.")
+
+(defun clojure-slime-config ()
+  "Load Clojure SLIME support out of the `clojure-src-root' directory.
+
+Since there's no single conventional place to keep Clojure, this
+is bundled up as a function so that you can call it after you've set
+`clojure-src-root' in your personal config."
+
+  (add-to-list 'load-path (concat clojure-src-root "/slime"))
+  (add-to-list 'load-path (concat clojure-src-root "/slime/contrib"))
+  (add-to-list 'load-path (concat clojure-src-root "/swank-clojure"))
+
+  (require 'slime-autoloads)
+  (require 'swank-clojure-autoload)
+
+  (eval-after-load 'slime '(slime-setup '(slime-fancy)))
+
+  (setq swank-clojure-jar-path (concat clojure-src-root "/clojure/clojure.jar")
+        swank-clojure-extra-classpaths
+        (list (concat clojure-src-root "/clojure-contrib/clojure-contrib.jar"))))
+
+(defun clojure-install (src-root)
+  "Perform the initial Clojure install along with Emacs support libs.
+
+This requires git, a JVM, ant, and an active Internet connection."
+  (interactive (list
+                (read-from-minibuffer (concat "Install Clojure in (default: "
+                                              clojure-src-root "): ")
+                                      nil nil nil nil clojure-src-root)))
+  (mkdir src-root t)
+
+  (if (file-exists-p (concat src-root "/clojure"))
+      (error "Clojure is already installed at %s/clojure" src-root))
+
+  (cd src-root)
+  (message "Checking out source... this will take a while...")
+  (dolist (cmd '("git clone git://github.com/kevinoneill/clojure.git"
+                 "git clone git://github.com/kevinoneill/clojure-contrib.git"
+                 "git clone git://github.com/jochu/swank-clojure.git"
+                 "git clone git://git.boinkor.net/slime.git"))
+    (unless (= 0 (shell-command cmd))
+      (error "Clojure installation step failed: %s" cmd)))
+
+  (message "Compiling...")
+  (cd (concat clojure-src-root "/clojure"))
+  (unless (= 0 (shell-command "ant")) (error "Couldn't compile Clojure."))
+  (cd (concat clojure-src-root "/clojure-contrib"))
+  (unless (= 0 (shell-command "ant")) (error "Couldn't compile Clojure contrib."))
+
+  (unless (equal src-root clojure-src-root)
+    (with-output-to-temp-buffer "clojure-install-note"
+      (princ (format "You've installed clojure in a non-default location. If you want to use this installation in the future, you will need to add the following line to your personal Emacs config somewhere:
+
+\(setq clojure-src-root \"%s\"\)" src-root)))
+    (setq clojure-src-root src-root))
+
+  (clojure-slime-config)
+
+  (message "Installed Clojure successfully. Press M-x slime to continue."))
+
 ;;;###autoload
 (add-to-list 'auto-mode-alist '("\\.clj$" . clojure-mode))