Add Database VM files.

Author: oraclebase

oci/oci_db/README.md

@@ -0,0 +1,9 @@
+# Terraform : Oracle Cloud Infrastructure (OCI) Database VM
+
+Usage description.
+
+* [Terraform : Oracle Cloud Infrastructure (OCI) Database VM](https://oracle-base.com/articles/misc/terraform-oci-database-vm).
+
+Related articles.
+
+* [Terraform : All Articles](https://oracle-base.com/articles/misc/articles-misc#terraform)

oci/oci_db/oci_db.tf

@@ -0,0 +1,89 @@
+# Variables
+variable "compartment_id"      { type = string }
+variable "db_admin_password"   { type = string }
+variable "db_name"             { type = string }
+variable "db_public_keys"      { type = list(string) }
+variable "db_subnet_id"        { type = string }
+variable "db_display_name"     { type = string }
+variable "db_pdb_name"         { type = string }
+variable "db_hostname"         { type = string }
+variable "db_host_domain"      { type = string }
+variable "db_storage_gb"       { type = number }
+
+variable "db_workload" {
+  type    = string
+  default = "OLTP"
+}
+
+variable "db_version" {
+  type    = string
+  default = "21.1.0.0"
+}
+
+variable "db_shape" {
+  type    = string
+  default = "VM.Standard2.1"
+}
+
+variable "db_database_edition" {
+  type    = string
+  default = "ENTERPRISE_EDITION_EXTREME_PERFORMANCE"
+}
+
+variable "db_license_model" {
+  type    = string
+  default = "LICENSE_INCLUDED"
+}
+
+variable "db_node_count" {
+  type    = number
+  default = 1
+}
+
+
+# Resources
+data "oci_identity_availability_domains" "ads" {
+  compartment_id = var.compartment_id
+}
+
+resource "oci_database_db_system" "tf_db" {
+  availability_domain = data.oci_identity_availability_domains.ads.availability_domains[0].name
+  compartment_id      = var.compartment_id
+  db_home {
+    database {
+      admin_password = var.db_admin_password
+      db_name        = var.db_name
+      db_workload    = var.db_workload
+      pdb_name       = var.db_pdb_name
+    }
+    db_version = var.db_version
+  }
+  hostname                = var.db_hostname
+  shape                   = var.db_shape
+  ssh_public_keys         = var.db_public_keys
+  subnet_id               = var.db_subnet_id
+  display_name            = var.db_display_name
+  data_storage_size_in_gb = var.db_storage_gb
+  database_edition        = var.db_database_edition
+  domain                  = var.db_host_domain
+  license_model           = var.db_license_model
+  node_count              = var.db_node_count
+}
+
+
+# Outputs
+output "db_display_name" {
+  value = oci_database_db_system.tf_db.display_name
+}
+
+output "db_id" {
+  value = oci_database_db_system.tf_db.id
+}
+
+output "db_state" {
+  value = oci_database_db_system.tf_db.state
+}
+
+output "first-availability-domain_name" {
+  value = data.oci_identity_availability_domains.ads.availability_domains[0].name
+}

oci/oci_db/oci_db_variables.auto.tfvars.example

@@ -0,0 +1,14 @@
+# Amend with your details.
+compartment_id      = "ocid1.compartment.oc1..aaaaaaaa..."
+db_admin_password   = "MyStrongPassword123--"
+db_host_domain      = "obdomain"
+db_name             = "cdb1"
+db_workload         = "OLTP"
+db_pdb_name         = "pdb1"
+db_version          = "21.1.0.0"
+db_hostname         = "obtest2"
+db_shape            = "VM.Standard2.1"
+db_public_keys      = ["ssh-rsa AAAAB3Nza..."]
+db_subnet_id        = "ocid1.subnet.oc1.uk-london-1.aaaaaaaa..."
+db_display_name     = "obtest2"
+db_storage_gb       = 256

oci/oci_db/oci_provider.tf

@@ -0,0 +1,17 @@
+# Variables.
+variable "tenancy_ocid"         { type = string }
+variable "user_ocid"            { type = string }
+variable "private_key_path"     { type = string }
+variable "fingerprint"          { type = string }
+variable "region"               { type = string }
+variable "root_compartment_id"  { type = string }
+
+
+# Resources
+provider "oci" {
+  tenancy_ocid     = var.tenancy_ocid
+  user_ocid        = var.user_ocid
+  private_key_path = var.private_key_path
+  fingerprint      = var.fingerprint
+  region           = var.region
+}

oci/oci_db/oci_provider_variables.auto.tfvars.example

@@ -0,0 +1,7 @@
+# Amend with your details.
+tenancy_ocid        = "ocid1.tenancy.oc1..aaaaaaaa..."
+user_ocid           = "ocid1.user.oc1..aaaaaaaa..."
+private_key_path    = "/path-to-my/.oci/my-oci-key.pem"
+fingerprint         = "a5:68:0f:46:6d:06:43:5a:38:98:74:??:??:??:??:??"
+region              = "uk-london-1"
+root_compartment_id = "ocid1.tenancy.oc1..aaaaaaaa..."