go-tree-sitter/flake.nix at master · tree-sitter/go-tree-sitter · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
{
  description = "Go bindings for the Tree-sitter parsing library";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    self.submodules = true;
  };

  outputs =
    inputs:
    let
      inherit (inputs.nixpkgs) lib;
      inherit (inputs) self;
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      eachSystem = lib.genAttrs systems;
      pkgsFor = inputs.nixpkgs.legacyPackages;
    in
    {
      packages = eachSystem (
        system:
        let
          pkgs = pkgsFor.${system};
          inherit (pkgs) lib;
        in
        {
          default = pkgs.buildGoModule {
            pname = "go-tree-sitter";
            version = "0.25.1";

            src = self;

            vendorHash = "sha256-6rj6oNohxBQt0LhIaHh3fQKHbNCsLsBkuPYNquHEVzE=";
            proxyVendor = true;

            subPackages = [ "." ];

            meta = {
              description = "Go bindings for Tree-sitter parsing library";
              homepage = "https://github.com/tree-sitter/go-tree-sitter";
              license = lib.licenses.mit;
              maintainers = [ lib.maintainers.amaanq ];
            };
          };
        }
      );

      devShells = eachSystem (
        system:
        let
          pkgs = pkgsFor.${system};
        in
        {
          default = pkgs.mkShell {
            buildInputs = [
              pkgs.go
              pkgs.gopls
            ];
          };
        }
      );

      checks = eachSystem (system: {
        inherit (self.packages.${system}) default;
      });
    };
}