Detect and bundle LV2 UI Suil modules

Related LMMS#7201

Author: tresf

CMakeLists.txt

@@ -267,6 +267,7 @@ IF(WANT_SUIL)
 		IF(SUIL_FOUND)
 			SET(LMMS_HAVE_SUIL TRUE)
 			SET(STATUS_SUIL "OK")
+			find_package(SuilModules)
 		ELSE()
 			SET(STATUS_SUIL "not found, install it or set PKG_CONFIG_PATH appropriately")
 		ENDIF()

cmake/apple/CMakeLists.txt

@@ -30,6 +30,8 @@ set(CPACK_PROJECT_NAME "${PROJECT_NAME}" PARENT_SCOPE)
 set(CPACK_PROJECT_VERSION "${VERSION}" PARENT_SCOPE)
 set(CPACK_PROJECT_NAME_UCASE "${PROJECT_NAME_UCASE}" PARENT_SCOPE)
 set(CPACK_PROJECT_URL "${PROJECT_URL}" PARENT_SCOPE)
+set(CPACK_SUIL_MODULES "${Suil_MODULES}" PARENT_SCOPE)
+set(CPACK_SUIL_MODULES_PREFIX "${Suil_MODULES_PREFIX}" PARENT_SCOPE)
 
 if(CMAKE_VERSION VERSION_LESS "3.19")
     message(WARNING "DMG creation requires at least CMake 3.19")

cmake/apple/MacDeployQt.cmake

@@ -60,6 +60,13 @@ file(COPY "${CPACK_CURRENT_SOURCE_DIR}/project.icns" DESTINATION "${APP}/Content
 file(COPY "${CPACK_CURRENT_SOURCE_DIR}/icon.icns" DESTINATION "${APP}/Contents/Resources")
 file(RENAME "${APP}/Contents/Resources/icon.icns" "${APP}/Contents/Resources/${lmms}.icns")
 
+# Copy Suil modules
+if(CPACK_SUIL_MODULES)
+	set(SUIL_MODULES_TARGET "${APP}/Contents/Frameworks/${CPACK_SUIL_MODULES_PREFIX}")
+	file(MAKE_DIRECTORY "${SUIL_MODULES_TARGET}")
+	file(COPY ${CPACK_SUIL_MODULES} DESTINATION "${SUIL_MODULES_TARGET}")
+endif()
+
 # Make all libraries writable for macdeployqt
 file(CHMOD_RECURSE "${APP}/Contents" PERMISSIONS
 	OWNER_EXECUTE OWNER_WRITE OWNER_READ

cmake/linux/CMakeLists.txt

@@ -36,6 +36,8 @@ set(CPACK_PROJECT_NAME "${PROJECT_NAME}" PARENT_SCOPE)
 set(CPACK_PROJECT_NAME_UCASE "${PROJECT_NAME_UCASE}" PARENT_SCOPE)
 set(CPACK_PROJECT_VERSION "${VERSION}" PARENT_SCOPE)
 set(CPACK_CMAKE_COMMAND "${CMAKE_COMMAND}" PARENT_SCOPE)
+set(CPACK_SUIL_MODULES "${Suil_MODULES}" PARENT_SCOPE)
+set(CPACK_SUIL_MODULES_PREFIX "${Suil_MODULES_PREFIX}" PARENT_SCOPE)
 
 # TODO: Canidate for DetectMachine.cmake
 if(IS_X86_64)

cmake/linux/LinuxDeploy.cmake

@@ -59,6 +59,13 @@ foreach(_file ${files})
 	endif()
 endforeach()
 
+# Copy Suil modules
+if(CPACK_SUIL_MODULES)
+	set(SUIL_MODULES_TARGET "${APP}/usr/lib/${CPACK_SUIL_MODULES_PREFIX}")
+	file(MAKE_DIRECTORY "${SUIL_MODULES_TARGET}")
+	file(COPY ${CPACK_SUIL_MODULES} DESTINATION "${SUIL_MODULES_TARGET}")
+endif()
+
 # Ensure project's "qmake" executable is first on the PATH
 get_filename_component(QTBIN "${CPACK_QMAKE_EXECUTABLE}" DIRECTORY)
 set(ENV{PATH} "${QTBIN}:$ENV{PATH}")

cmake/modules/FindSuilModules.cmake

@@ -0,0 +1,40 @@
+# Copyright (c) 2024 Tres Finocchiaro
+#
+# Redistribution and use is allowed according to the terms of the New BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+
+# This module defines
+# Suil_MODULES: List of full paths to Suil modules (e.g. "/usr/lib/suil-0/libsuil_x11.so;...")
+# Suil_MODULES_PREFIX: Only the directory name of the Suil_MODULES path (e.g. "suil-0")
+
+pkg_check_modules(Suil QUIET suil-0)
+
+if(Suil_FOUND)
+	if(APPLE)
+		set(_lib_ext "dylib")
+	elseif(WIN32)
+		set(_lib_ext "dll")
+	else()
+		set(_lib_ext "so")
+	endif()
+
+	# Isolate -- if needed -- the first suil library path (e.g. "/usr/lib/libsuil-0.so")
+	list(GET Suil_LINK_LIBRARIES 0 _lib)
+	if(EXISTS "${_lib}")
+		# Isolate -- if needed -- the first suil library name (e.g. "suil-0")
+		list(GET Suil_LIBRARIES 0 _modules_prefix)
+		get_filename_component(_lib_dir "${_lib}" DIRECTORY)
+		# Construct modules path (e.g. "/usr/lib/suil-0")
+		set(_modules_dir "${_lib_dir}/${_modules_prefix}")
+		if(IS_DIRECTORY "${_modules_dir}")
+			set(Suil_MODULES_PREFIX "${_modules_prefix}")
+			file(GLOB Suil_MODULES "${_modules_dir}/*.${_lib_ext}")
+			list(SORT Suil_MODULES)
+		endif()
+	endif()
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(SuilModules
+	REQUIRED_VARS Suil_MODULES Suil_MODULES_PREFIX
+)