Add ERC827 Token

contracts/mocks/ERC827TokenMock.sol

@@ -0,0 +1,15 @@
+pragma solidity ^0.4.13;
+
+
+import '../token/ERC827.sol';
+
+
+// mock class using ERC827 Token
+contract ERC827TokenMock is ERC827 {
+
+  function ERC827TokenMock(address initialAccount, uint256 initialBalance) {
+    balances[initialAccount] = initialBalance;
+    totalSupply = initialBalance;
+  }
+
+}

contracts/mocks/MessageHelper.sol

@@ -0,0 +1,25 @@
+pragma solidity ^0.4.11;
+
+contract MessageHelper {
+
+  event Show(bytes32 b32, uint256 number, string text);
+
+  function showMessage(
+    bytes32 message, uint256 number, string text
+  ) returns (bool) {
+    Show(message, number, text);
+    return true;
+  }
+
+  function fail() {
+    throw;
+  }
+
+  function call(address to, bytes data) returns (bool) {
+    if (to.call(data))
+      return true;
+    else
+      return false;
+  }
+
+}

contracts/token/ERC827.sol

@@ -0,0 +1,81 @@
+pragma solidity ^0.4.13;
+
+import "./StandardToken.sol";
+
+/**
+   @title ERC827, an extension of ERC20 token standard
+
+   Implementation the ERC827, following the ERC20 standard with extra
+   methods to transfer value and data and execute calls in transfers and
+   approvals.
+   Uses OpenZeppelin StandardToken.
+ */
+contract ERC827 is StandardToken {
+
+  /**
+     @dev Addition to ERC20 token methods. It allows to
+     approve the transfer of value and execute a call with the sent data.
+
+     Beware that changing an allowance with this method brings the risk that
+     someone may use both the old and the new allowance by unfortunate
+     transaction ordering. One possible solution to mitigate this race condition
+     is to first reduce the spender's allowance to 0 and set the desired value
+     afterwards:
+     https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
+
+     @param _spender The address that will spend the funds.
+     @param _value The amount of tokens to be spent.
+     @param _data ABI-encoded contract call to call `_to` address.
+
+     @return true if the call function was executed successfully
+   */
+  function approve(address _spender, uint256 _value, bytes _data) public returns (bool) {
+    require(_spender != address(this));
+
+    super.approve(_spender, _value);
+
+    require(_spender.call(_data));
+
+    return true;
+  }
+
+  /**
+     @dev Addition to ERC20 token methods. Transfer tokens to a specified
+     address and execute a call with the sent data on the same transaction
+
+     @param _to address The address which you want to transfer to
+     @param _value uint256 the amout of tokens to be transfered
+     @param _data ABI-encoded contract call to call `_to` address.
+
+     @return true if the call function was executed successfully
+   */
+  function transfer(address _to, uint256 _value, bytes _data) public returns (bool) {
+    require(_to != address(this));
+
+    super.transfer(_to, _value);
+
+    require(_to.call(_data));
+    return true;
+  }
+
+  /**
+     @dev Addition to ERC20 token methods. Transfer tokens from one address to
+     another and make a contract call on the same transaction
+
+     @param _from The address which you want to send tokens from
+     @param _to The address which you want to transfer to
+     @param _value The amout of tokens to be transferred
+     @param _data ABI-encoded contract call to call `_to` address.
+
+     @return true if the call function was executed successfully
+   */
+  function transferFrom(address _from, address _to, uint256 _value, bytes _data) public returns (bool) {
+    require(_to != address(this));
+
+    super.transferFrom(_from, _to, _value);
+
+    require(_to.call(_data));
+    return true;
+  }
+
+}