Revert "Remove PegJS since it is no longer used"

This reverts commit 9c5cc57.

blocks/api/parser.js

@@ -7,6 +7,7 @@ import { escape, unescape } from 'lodash';
 /**
  * Internal dependencies
  */
+import { parse as grammarParse } from './post.pegjs';
 import { getBlockSettings, getUnknownTypeHandler } from './registration';
 import { createBlock } from './factory';
 

blocks/api/post.pegjs

@@ -0,0 +1,95 @@
+Document
+  = WP_Block_List
+
+WP_Block_List
+  = WP_Block*
+
+WP_Block
+  = WP_Block_Balanced
+  / WP_Block_Html
+
+WP_Block_Balanced
+  = s:WP_Block_Start ts:(!WP_Block_End c:Any { return c })+ e:WP_Block_End & { return s.blockType === e.blockType }
+  { return {
+    blockType: s.blockType,
+    attrs: s.attrs,
+    rawContent: ts.join( '' ),
+  } }
+
+WP_Block_Html
+  = ts:(!WP_Block_Balanced c:Any { return c })+
+  {
+    return {
+      attrs: {},
+      rawContent: ts.join( '' )
+    }
+  }
+
+WP_Block_Start
+  = "<!--" __ "wp:" blockType:WP_Block_Type attrs:WP_Block_Attribute_List _? "-->"
+  { return {
+    blockType: blockType,
+    attrs: attrs
+  } }
+
+WP_Block_End
+  = "<!--" __ "/wp:" blockType:WP_Block_Type __ "-->"
+  { return {
+    blockType: blockType
+  } }
+
+WP_Block_Type
+  = head:ASCII_Letter tail:WP_Block_Type_Char*
+  { return [ head ].concat( tail ).join( '' ) }
+
+WP_Block_Attribute_List
+  = as:(_+ attr:WP_Block_Attribute { return attr })*
+  { return as.reduce( function( attrs, pair ) {
+    attrs[ pair.name ] = [ pair.value ];
+    return attrs;
+  }, {} ) }
+
+WP_Block_Attribute
+  = name:WP_Block_Attribute_Name ":" value:WP_Block_Attribute_Value
+  { return [ name, value ] }
+
+WP_Block_Attribute_Name
+  = head:ASCII_Letter tail:ASCII_AlphaNumeric*
+  { return [ head ].concat( tail ).join( '' )  }
+
+WP_Block_Attribute_Value
+  = head:ASCII_Letter tail:WP_Block_Attribute_Value_Char*
+  { return [ head ].concat( tail ).join( '' ) }
+
+WP_Block_Type_Char
+ = ASCII_AlphaNumeric
+ / [\/]
+
+ASCII_AlphaNumeric
+  = ASCII_Letter
+  / ASCII_Digit
+  / Special_Chars
+
+WP_Block_Attribute_Value_Char
+  = [^ \t\r\n]
+
+ASCII_Letter
+  = [a-zA-Z]
+
+ASCII_Digit
+  = [0-9]
+
+Special_Chars
+  = [\-\_]
+
+Newline
+  = [\r\n]
+
+_
+  = [ \t]
+
+__
+  = _+
+
+Any
+  = .

package.json

@@ -42,6 +42,8 @@
     "jsdom": "^9.12.0",
     "mocha": "^3.2.0",
     "node-sass": "^4.5.0",
+    "pegjs": "^0.10.0",
+    "pegjs-loader": "^0.5.1",
     "postcss-loader": "^1.3.3",
     "raw-loader": "^0.5.1",
     "react": "^15.4.2",

webpack.config.js

@@ -26,6 +26,10 @@ const config = {
 	},
 	module: {
 		rules: [
+			{
+				test: /\.pegjs/,
+				use: 'pegjs-loader'
+			},
 			{
 				test: /\.js$/,
 				exclude: /node_modules/,