[stable30] chore: Add nix flake with development shell

.envrc

@@ -0,0 +1,3 @@
+watch_file lib/versioncheck.php
+watch_file package.json
+use flake

.gitignore

@@ -182,3 +182,5 @@ core/js/mimetypelist.js
 cypress/downloads
 cypress/snapshots
 cypress/videos
+
+/.direnv

.reuse/dep5

@@ -342,3 +342,7 @@ License: CC0-1.0
 Files: apps/theming/fonts/OpenDyslexic-Bold.otf apps/theming/fonts/OpenDyslexic-Regular.otf
 Copyright: 2012-2019 Abbie Gonzalez <https://abbiecod.es|[email protected]>, with Reserved Font Name OpenDyslexic.
 License: OFL-1.1-RFN
+
+Files: .envrc flake.nix flake.lock
+Copyright: 2025 Nextcloud GmbH and Nextcloud contributors
+License: AGPL-3.0-or-later

build/files-checker.php

@@ -11,6 +11,7 @@
 	'..',
 	'.devcontainer',
 	'.editorconfig',
+	'.envrc',
 	'.eslintignore',
 	'.eslintrc.js',
 	'.git',
@@ -62,6 +63,8 @@
 	'cypress.d.ts',
 	'cypress',
 	'dist',
+	'flake.lock',
+	'flake.nix',
 	'index.html',
 	'index.php',
 	'jest.config.ts',

flake.nix

@@ -0,0 +1,88 @@
+{
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixos-25.05";
+    flake-utils.url = "github:numtide/flake-utils";
+  };
+
+  outputs = { nixpkgs, flake-utils, ... }:
+    flake-utils.lib.eachDefaultSystem (system:
+      let
+        pkgs = nixpkgs.legacyPackages.${system};
+        lib = pkgs.lib;
+      in
+      {
+        devShells.default =
+          let
+            php_version = lib.strings.concatStrings (builtins.match ".*PHP_VERSION_ID < ([0-9])0([0-9])00.*" (builtins.readFile ./lib/versioncheck.php));
+            php = pkgs.pkgs."php${php_version}".buildEnv {
+              # Based off https://docs.nextcloud.com/server/latest/admin_manual/installation/php_configuration.html
+              extensions = ({ enabled, all }: enabled ++ (with all; [
+                # Required
+                ctype
+                curl
+                dom
+                fileinfo
+                filter
+                gd
+                mbstring
+                openssl
+                posix
+                session
+                simplexml
+                xmlreader
+                xmlwriter
+                zip
+                zlib
+                # Database connectors
+                pdo_sqlite
+                pdo_mysql
+                pdo_pgsql
+                # Recommended
+                intl
+                sodium
+                # Required for specific apps
+                ldap
+                smbclient
+                ftp
+                imap
+                # Recommended for specific apps (optional)
+                gmp
+                exif
+                # For enhanced server performance (optional)
+                apcu
+                memcached
+                redis
+                # For preview generation (optional)
+                imagick
+                # For command line processing (optional)
+                pcntl
+
+                # Debugging
+                xdebug
+              ]));
+
+              extraConfig = ''
+                max_execution_time=300
+                memory_limit=-1
+
+                xdebug.mode=debug
+              '';
+            };
+            node_version = builtins.substring 1 (-1) (builtins.elemAt (lib.strings.splitString "." (builtins.fromJSON (builtins.readFile ./package.json)).engines.node) 0);
+            node = pkgs."nodejs_${node_version}";
+          in
+          pkgs.mkShell {
+            NOCOVERAGE = 1;
+
+            packages = [
+              php
+              php.packages.composer
+              node
+              # Preview generation
+              pkgs.ffmpeg
+              pkgs.libreoffice
+            ];
+          };
+      }
+    );
+}