Fetch versions directly from npm registry url

src/NpmRegistry.res

@@ -0,0 +1,43 @@
+type response = {
+  ok: bool,
+  json: unit => promise<Js.Json.t>,
+}
+
+@val external fetch: string => promise<response> = "fetch"
+
+@scope(("process", "env"))
+external npm_config_registry: option<string> = "NPM_CONFIG_REGISTRY"
+
+@inline
+let defaultRegistryUrl = "https://registry.npmjs.org"
+
+let getNpmRegistry = () =>
+  npm_config_registry
+  ->Option.flatMap(registry => registry->Node.Url.make)
+  ->Option.mapOr(defaultRegistryUrl, url => url->Node.Url.href)
+
+let getPackageVersions = async (packageName, range) => {
+  let registry = getNpmRegistry()
+
+  switch await fetch(`${registry}/${packageName}`) {
+  | response if response.ok =>
+    let versions = switch await response.json() {
+    | Object(dict) =>
+      switch dict->Dict.get("versions") {
+      | Some(Object(dict)) =>
+        dict
+        ->Dict.keysToArray
+        ->Array.filterMap(version =>
+          version->CompareVersions.satisfies(range) ? Some(version) : None
+        )
+      | _ => []
+      }
+    | _ => []
+    }
+
+    versions->Array.reverse
+    versions
+
+  | _responseNotOk => []
+  }
+}

src/RescriptVersions.res

@@ -5,24 +5,6 @@ let rescriptCoreVersionRange = ">=1.0.0"
 
 type versions = {rescriptVersion: string, rescriptCoreVersion: string}
 
-let getPackageVersions = async (packageName, range) => {
-  let {stdout} = await Node.Promisified.ChildProcess.exec(`npm view ${packageName} versions --json`)
-
-  let versions = switch JSON.parseExn(stdout) {
-  | Array(versions) =>
-    versions->Array.filterMap(json =>
-      switch json {
-      | String(version) if version->CompareVersions.satisfies(range) => Some(version)
-      | _ => None
-      }
-    )
-  | _ => []
-  }
-
-  versions->Array.reverse
-  versions
-}
-
 let getCompatibleRescriptCoreVersions = (~rescriptVersion, ~rescriptCoreVersions) =>
   if CompareVersions.compareVersions(rescriptVersion, "11.1.0")->Ordering.isLess {
     rescriptCoreVersions->Array.filter(coreVersion =>
@@ -37,10 +19,12 @@ let promptVersions = async () => {
 
   s->P.Spinner.start("Loading available versions...")
 
-  let (rescriptVersions, rescriptCoreVersions) = await Promise.all2((
-    getPackageVersions("rescript", rescriptVersionRange),
-    getPackageVersions("@rescript/core", rescriptCoreVersionRange),
-  ))
+  let (rescriptVersions, rescriptCoreVersions) = try await Promise.all2((
+    NpmRegistry.getPackageVersions("rescript", rescriptVersionRange),
+    NpmRegistry.getPackageVersions("@rescript/core", rescriptCoreVersionRange),
+  )) catch {
+  | _exn => Error.make("Fetching versions from registry failed.")->Error.raise
+  }
 
   s->P.Spinner.stop("Versions loaded.")
 

src/bindings/Node.res

@@ -64,6 +64,14 @@ module Url = {
   type t
 
   @module("node:url") external fileURLToPath: t => string = "fileURLToPath"
+
+  @new external makeUnsafe: string => t = "URL"
+  @get external href: t => string = "href"
+
+  let make = string =>
+    try Some(makeUnsafe(string)) catch {
+    | _exn => None
+    }
 }
 
 module Os = {