Add code in FlutterViewController and VSyncClient

shell/platform/darwin/ios/framework/Source/FlutterViewController.mm

@@ -65,6 +65,9 @@ @interface FlutterViewController () <FlutterBinaryMessenger, UIScrollViewDelegat
 @property(nonatomic, assign) double targetViewInsetBottom;
 @property(nonatomic, retain) VSyncClient* keyboardAnimationVSyncClient;
 
+/// VSyncClient for touch callback's rate correction.
+@property(nonatomic, retain) VSyncClient* touchRateCorrectionVSyncClient;
+
 /*
  * Mouse and trackpad gesture recognizers
  */
@@ -671,6 +674,9 @@ - (void)viewDidLoad {
   // Register internal plugins.
   [self addInternalPlugins];
 
+  // Setup vsync client to correct touch rate.
+  [self setupTouchRateCorrectionVSyncClient];
+
   if (@available(iOS 13.4, *)) {
     _hoverGestureRecognizer =
         [[UIHoverGestureRecognizer alloc] initWithTarget:self action:@selector(hoverEvent:)];
@@ -833,6 +839,7 @@ - (void)dealloc {
   [self deregisterNotifications];
 
   [self invalidateKeyboardAnimationVSyncClient];
+  [self invalidateTouchRateCorrectionVSyncClient];
   _scrollView.get().delegate = nil;
   _hoverGestureRecognizer.delegate = nil;
   [_hoverGestureRecognizer release];
@@ -966,6 +973,9 @@ - (void)dispatchTouches:(NSSet*)touches
     }
   }
 
+  // Activate or pause touch rate correction according to the touches when user is interacting.
+  [self triggerTouchRateCorrectionIfNeeded:touches];
+
   const CGFloat scale = [UIScreen mainScreen].scale;
   auto packet =
       std::make_unique<flutter::PointerDataPacket>(touches.count + touches_to_remove_count);
@@ -1111,6 +1121,53 @@ - (void)forceTouchesCancelled:(NSSet*)touches {
   [self dispatchTouches:touches pointerDataChangeOverride:&cancel event:nullptr];
 }
 
+#pragma mark - Touch events rate correction
+
+- (void)setupTouchRateCorrectionVSyncClient {
+  NSAssert(_touchRateCorrectionVSyncClient == nil,
+           @"_touchRateCorrectionVSyncClient should be nil when setup");
+  double displayRefreshRate = [DisplayLinkManager displayRefreshRate];
+  if (displayRefreshRate <= 60) {
+    // If current device's max frame rate is not larger than 60HZ, the delivery rate of touch events
+    // is the same with render vsync rate. So we don't need to create
+    // _touchRateCorrectionVSyncClient to correct touch callback's rate.
+    return;
+  }
+
+  flutter::Shell& shell = [_engine.get() shell];
+  auto callback = [](std::unique_ptr<flutter::FrameTimingsRecorder> recorder) {
+    // Do nothing in this block. Just trigger system to callback touch events with correct rate.
+  };
+  _touchRateCorrectionVSyncClient =
+      [[VSyncClient alloc] initWithTaskRunner:shell.GetTaskRunners().GetPlatformTaskRunner()
+                                     callback:callback];
+  _touchRateCorrectionVSyncClient.allowPauseAfterVsync = NO;
+}
+
+- (void)triggerTouchRateCorrectionIfNeeded:(NSSet*)touches {
+  // As long as there is a touch's phase is UITouchPhaseBegan or UITouchPhaseMoved,
+  // we should activate the correction. Otherwise we will pause the correction.
+  BOOL isUserInteracting = NO;
+  for (UITouch* touch in touches) {
+    if (touch.phase == UITouchPhaseBegan || touch.phase == UITouchPhaseMoved) {
+      isUserInteracting = YES;
+      break;
+    }
+  }
+
+  if (isUserInteracting && [_engine.get() viewController] == self) {
+    [_touchRateCorrectionVSyncClient await];
+  } else {
+    [_touchRateCorrectionVSyncClient pause];
+  }
+}
+
+- (void)invalidateTouchRateCorrectionVSyncClient {
+  [_touchRateCorrectionVSyncClient invalidate];
+  [_touchRateCorrectionVSyncClient release];
+  _touchRateCorrectionVSyncClient = nil;
+}
+
 #pragma mark - Handle view resizing
 
 - (void)updateViewportMetrics {

shell/platform/darwin/ios/framework/Source/vsync_waiter_ios.h

@@ -45,6 +45,8 @@
 
 - (void)await;
 
+- (void)pause;
+
 - (void)invalidate;
 
 - (double)getRefreshRate;

shell/platform/darwin/ios/framework/Source/vsync_waiter_ios.mm

@@ -97,6 +97,10 @@ - (void)await {
   display_link_.get().paused = NO;
 }
 
+- (void)pause {
+  display_link_.get().paused = YES;
+}
+
 - (void)onDisplayLink:(CADisplayLink*)link {
   TRACE_EVENT0("flutter", "VSYNC");